L'exécution d'une Requête Access à partir d'Excel

La première chose que vous devez faire est de configurer votre parametereized requête dans Access. Donc, dire, Requête1 est (où ID est un entier):

SELECT ID FROM Table1 WHERE ID = [MyID];

Les crochets autour de l' [MyID], si elle n'aboutit pas à un nom de champ, sera considéré comme un Paramètre. Maintenant, dire, nous voulons ramener le dossier avec l'ID 1. Configurer votre code dans Excel:

Sub testdb()

    Dim con As ADODB.Connection
    Dim cmd As ADODB.Command
    Dim prm As ADODB.Parameter
    Dim rs As ADODB.Recordset

    Set con = New ADODB.Connection
    Set cmd = New ADODB.Command

    With con
        .Provider = "Microsoft.ACE.OLEDB.12.0"
        .Open "H:\WBC\Lukas\STOP.accdb"
    End With

    With cmd
        .ActiveConnection = con
        .CommandText = "Query1"
        .CommandType = adCmdStoredProc

        .Parameters.Append cmd.CreateParameter("MyID", adInteger, adParamInput)
        .Parameters("MyID") = 1
    End With

    Set rs = New ADODB.Recordset
    rs.Open cmd

    Do Until rs.EOF
        Debug.Print rs.Fields("ID").Value
        rs.MoveNext
    Loop

    rs.Close
    con.Close

    Set cmd = Nothing
    Set rs = Nothing
    Set prm = Nothing
    Set con = Nothing

End Sub

Cette référence les types de données adinteger trouvé dans cette ligne

.Parameters.Append cmd.CreateParameter("MyID", adInteger, adParamInput)

doit être remplacé par la bonne constante qui représente le type de variable (voir ici: http://www.w3schools.com/ado/met_comm_createparameter.asp) du Paramètre dans votre requête. Dans votre cas, vous devez définir la valeur du Paramètre qui est représentée dans cette ligne

.Parameters("MyID") = 1

avec la valeur de votre cellule.

Et c'est tout. Ainsi, vous créez la Connexion, créez un objet de Commande (qui est essentiellement une référence à votre requête Access), la Commande propriétés de l'objet, y compris le paramètre, puis les résultats sont rapportés dans un jeu d'enregistrements. Ensuite une boucle à travers le jeu d'enregistrements et de faire ce que vous voulez avec les valeurs.