Tri d'une taille variable tableau dans excel

Ce que je suis en train de faire est de sélectionner un tableau dans une feuille de calcul, puis les trier en fonction de 2 colonnes différentes

J'ai généré ce code avec l'enregistrement de la macro option. Les changements de table en taille, ce qui est pourquoi j'ai utilisé le xlDown, malheureusement le code par la suite les références exactes des cellules B4:B52". Une idée de comment je pourrais résoudre ce problème?

Range("B4:J4").Select
Range(Selection, Selection.End(xlDown)).Select
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range( _
    "B4:B52"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range( _
    "G4:G52"), SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets("Sheet1").Sort
    .SetRange Range("B4:J52")
    .Header = xlGuess
    .MatchCase = False
    .Orientation = xlTopToBottom
    .SortMethod = xlPinYin
    .Apply
End With
InformationsquelleAutor Chris | 2013-11-18
  1. 11

    Puisque vous êtes le tri des Table (ListObject en VBA), vous aurez envie de vous y référer. Cela permettra d'ajuster de façon dynamique pour englober l'ensemble des colonnes de la table. Dans cet exemple, les en-têtes de colonne/noms triés sont "Data1" et "Data3":

    Sub SortTable()
Dim lo As Excel.ListObject

'change this assignment to suit your table location and name
Set lo = ActiveWorkbook.Worksheets("Sheet1").ListObjects("Table1")
With lo
.Sort.SortFields.Clear
    .Sort.SortFields.Add _
        Key:=Range("Table1[data1]"), SortOn:=xlSortOnValues, Order:=xlAscending, _
        DataOption:=xlSortNormal
    .Sort.SortFields.Add _
        Key:=Range("Table1[data3]"), SortOn:=xlSortOnValues, Order:=xlAscending, _
        DataOption:=xlSortNormal
    With .Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End With
End Sub
    InformationsquelleAutor Doug Glancy
  2. 0

    Je voudrais trier les colonnes dans le tableau de la façon suivante:

    Sub SortingTable()
Dim ws As Worksheet
    set ws = ActiveSheet
Dim target_table As ListObject
    Set target_table = ws.ListObjects(wsName)
Dim sort_column_index As Long
    sort_column_index = target_table.ListColumns("ColumnToBeSortedName").Index
Dim sort_column As Range
    Set sort_column = target_table.ListColumns(sort_column_index).Range

' Applying the sorting to the table
With target_table.Sort
    .SortFields.Clear
    .SortFields.Add Key:=sort_column _
        , SortOn:=xlSortOnValues, Order:=xlAscending _
        , DataOption:=xlSortNormal
    .Apply
End With    
End Sub

    En fait, la seule différence est que vous déclarez une Gamme et d'attribuer celui-ci à la colonne de la table qui doit être triée. Faisant de cette façon, vous êtes en mesure d'appliquer la macro de tableaux sur différentes feuilles en supposant que les tables contiennent la colonne avec le nom "ColumnToBeSortedName".

    InformationsquelleAutor Petrushchak Bohdan