Vim auto-générer ctags

au BufWritePost *.c,*.cpp,*.h silent! !ctags -R &

L'inconvénient est que vous n'aurez pas utile balises du fichier jusqu'à la fin. Aussi longtemps que vous êtes sur un *nix système, il devrait être ok pour faire de multiples écrit avant que la précédente ctags terminé, mais vous devez le tester. Sur un système Windows de ne pas mettre en arrière-plan et il va se plaindre que le fichier est verrouillé jusqu'à ce que le premier ctags finitions (ce qui ne devrait pas causer des problèmes dans vim, mais vous vous retrouverez avec un peu obsolète fichier de tags).

Note, vous pouvez utiliser le --append option tonylo suggère, mais alors vous devrez peut-être désactiver tagbsearch qui peut signifier que l'étiquette de recherches prendra beaucoup plus de temps, selon la taille de votre fichier de balises.

J'ai écrit easytags.vim pour faire juste cela: mettre à jour automatiquement et de mettre en évidence les balises. Le plug-in peut être configuré pour la mise à jour, le fichier en cours d'édition ou tous les fichiers dans le répertoire du fichier en cours d'édition (de manière récursive). Il peut utiliser un mondial des balises du fichier, type de fichier spécifique des balises de fichiers et de projets spécifiques des balises de fichiers.

Peut-être utiliser l'ajout de l'argument de ctags comme l'ont démontré:

http://vim.wikia.com/wiki/Autocmd_to_update_ctags_file

Je ne peux pas vraiment se porter garant pour ce que j'utilise généralement source d'idées pour le code de la navigation, mais utiliser vim comme éditeur... allez comprendre.

Pour supprimer le message "appuyez sur enter" de l'invite, utilisez :silent.

Dans mon opninion, plugin Indexation est mieux.

http://www.vim.org/scripts/script.php?script_id=3221

Il peut être:

1) un add-on pour project.tar.gz

2) un plugin indépendant

• fond tags génération (vous n'avez pas attendre que ctags œuvres)
• plusieurs projets soutenus

La --append option est en effet la voie à suivre. Utilisé avec un grep -v, nous pouvons mettre à jour un seul tagged fichier. Par exemple, voici un extrait d'un mat plugin qui traite de cette question. (NB: Il faudra un "externe" bibliothèque plugin)

" Options {{{1
let g:tags_options_cpp = '--c++-kinds=+p --fields=+imaS --extra=+q'

function! s:CtagsExecutable()
  let tags_executable = lh#option#Get('tags_executable', s:tags_executable, 'bg')
  return tags_executable
endfunction

function! s:CtagsOptions()
  let ctags_options = lh#option#Get('tags_options_'.&ft, '')
  let ctags_options .= ' '.lh#option#Get('tags_options', '', 'wbg')
  return ctags_options
endfunction

function! s:CtagsDirname()
  let ctags_dirname = lh#option#Get('tags_dirname', '', 'b').'/'
  return ctags_dirname
endfunction

function! s:CtagsFilename()
  let ctags_filename = lh#option#Get('tags_filename', 'tags', 'bg')
  return ctags_filename
endfunction

function! s:CtagsCmdLine(ctags_pathname)
  let cmd_line = s:CtagsExecutable().' '.s:CtagsOptions().' -f '.a:ctags_pathname
  return cmd_line
endfunction


" ######################################################################
" Tag generating functions {{{1
" ======================================================================
" Interface {{{2
" ======================================================================
" Mappings {{{3
" inoremap <expr> ; <sid>Run('UpdateTags_for_ModifiedFile',';')

nnoremap <silent> <Plug>CTagsUpdateCurrent :call <sid>UpdateCurrent()<cr>
if !hasmapto('<Plug>CTagsUpdateCurrent', 'n')
  nmap <silent> <c-x>tc  <Plug>CTagsUpdateCurrent
endif

nnoremap <silent> <Plug>CTagsUpdateAll     :call <sid>UpdateAll()<cr>
if !hasmapto('<Plug>CTagsUpdateAll', 'n')
  nmap <silent> <c-x>ta  <Plug>CTagsUpdateAll
endif


" ======================================================================
" Auto command for automatically tagging a file when saved {{{3
augroup LH_TAGS
  au!
  autocmd BufWritePost,FileWritePost * if ! lh#option#Get('LHT_no_auto', 0) | call s:Run('UpdateTags_for_SavedFile') | endif
aug END

" ======================================================================
" Internal functions {{{2
" ======================================================================
" generate tags on-the-fly {{{3
function! UpdateTags_for_ModifiedFile(ctags_pathname)
  let source_name    = expand('%')
  let temp_name      = tempname()
  let temp_tags      = tempname()

  " 1- purge old references to the source name
  if filereadable(a:ctags_pathname)
    " it exists => must be changed
    call system('grep -v "  '.source_name.' " '.a:ctags_pathname.' > '.temp_tags.
      \ ' && mv -f '.temp_tags.' '.a:ctags_pathname)
  endif

  " 2- save the unsaved contents of the current file
  call writefile(getline(1, '$'), temp_name, 'b')

  " 3- call ctags, and replace references to the temporary source file to the
  " real source file
  let cmd_line = s:CtagsCmdLine(a:ctags_pathname).' '.source_name.' --append'
  let cmd_line .= ' && sed "s#\t'.temp_name.'\t#\t'.source_name.'\t#" > '.temp_tags
  let cmd_line .= ' && mv -f '.temp_tags.' '.a:ctags_pathname
  call system(cmd_line)
  call delete(temp_name)

  return ';'
endfunction

" ======================================================================
" generate tags for all files {{{3
function! s:UpdateTags_for_All(ctags_pathname)
  call delete(a:ctags_pathname)
  let cmd_line  = 'cd '.s:CtagsDirname()
  " todo => use project directory
  "
  let cmd_line .= ' && '.s:CtagsCmdLine(a:ctags_pathname).' -R'
  echo cmd_line
  call system(cmd_line)
endfunction

" ======================================================================
" generate tags for the current saved file {{{3
function! s:UpdateTags_for_SavedFile(ctags_pathname)
  let source_name    = expand('%')
  let temp_tags      = tempname()

  if filereadable(a:ctags_pathname)
    " it exists => must be changed
    call system('grep -v "  '.source_name.' " '.a:ctags_pathname.' > '.temp_tags.' && mv -f '.temp_tags.' '.a:ctags_pathname)
  endif
  let cmd_line = 'cd '.s:CtagsDirname()
  let cmd_line .= ' && ' . s:CtagsCmdLine(a:ctags_pathname).' --append '.source_name
  " echo cmd_line
  call system(cmd_line)
endfunction

" ======================================================================
" (public) Run a tag generating function {{{3
function! LHTagsRun(tag_function)
  call s:Run(a:tag_function)
endfunction

" ======================================================================
" (private) Run a tag generating function {{{3
" See this function as a /template method/.
function! s:Run(tag_function)
  try
    let ctags_dirname  = s:CtagsDirname()
    if strlen(ctags_dirname)==1
      throw "tags-error: empty dirname"
    endif
    let ctags_filename = s:CtagsFilename()
    let ctags_pathname = ctags_dirname.ctags_filename
    if !filewritable(ctags_dirname) && !filewritable(ctags_pathname)
      throw "tags-error: ".ctags_pathname." cannot be modified"
    endif

    let Fn = function("s:".a:tag_function)
    call Fn(ctags_pathname)
  catch /tags-error:/
    " call lh#common#ErrorMsg(v:exception)
    return 0
  finally
  endtry

  echo ctags_pathname . ' updated.'
  return 1
endfunction

function! s:Irun(tag_function, res)
  call s:Run(a:tag_function)
  return a:res
endfunction

" ======================================================================
" Main function for updating all tags {{{3
function! s:UpdateAll()
  let done = s:Run('UpdateTags_for_All')
endfunction

" Main function for updating the tags from one file {{{3
" @note the file may be saved or "modified".
function! s:UpdateCurrent()
  if &modified
    let done = s:Run('UpdateTags_for_ModifiedFile')
  else
    let done = s:Run('UpdateTags_for_SavedFile')
  endif
endfunction

Ce code définit:

• ^Xta pour forcer la mise à jour des balises de base pour tous les fichiers dans le projet en cours ;
• ^Xtc pour forcer la mise à jour des balises de base pour le courant (non enregistrées) fichier ;
• un autocommand qui met à jour les balises de base à chaque fois qu'un fichier est enregistré ;
  et il prend en charge et de nombreuses options pour désactiver la mise à jour automatique où nous n'en voulons pas, pour accorder ctags appels en fonction de types de fichiers, ...
  Il n'est pas juste un conseil, mais un petit extrait d'un plugin.

HTH,