XSL si la condition else

J'ai une exigence où j'aimerais avoir si d'autre instruction pour vérifier si un nœud possède les attributs d'ou il vient de chaîne.

Par exemple: 1 du nœud a 0 File(s) found et l'autre a attribs comme <autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='64' filename='AFP_p.tgp' />

Ci-dessous est un échantillon de deux nœuds

<product>
<autoIncludeUser>0 File(s) found</autoIncludeUser>
<autoIncludeSystem>
<autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='64' filename='AFP_p.tgp' />
<autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='3,879' filename='AnalystsExpressionMacros.tgp' />
<autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='475' filename='base64Converter.tgp' />
<autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='&lt;DIR&gt;' filename='codePages' />
</autoIncludeSystem>
<autoIncludeStudio>0 File(s) found</autoIncludeStudio>
<externalLibrarySystem>
<externalLibrarySystem_info mdate='08/23/2011' mtime='09:52' ampm='PM' filesize='196,608' filename='AFPtoXML_DP.dll' />
<externalLibrarySystem_info mdate='08/23/2011' mtime='09:52' ampm='PM' filesize='13,259' filename='ASN1toXSDRunner.jar' />
<externalLibrarySystem>
</product>

Comment puis-je déterminer si un nœud a juste les cordes ou les attribs et, d'après ce que je peux obtenir les valeurs String ou attrib values respectivement.

  • Bonne question, +1. Voir ma réponse pour un seul XPath 1.0 expression qui met en œuvre le voulait if then else logique. 🙂 J'ai fourni une transformation XSLT-vérification et une explication détaillée.
  • Ajout également d'une XPath 2.0 solution.
  • Après avoir pris un coup d'oeil à votre XML, vous devez utiliser xs:dateTime et xs:long au lieu de la merde, American-style de types.
InformationsquelleAutor abi1964 | 2011-08-30
  1. 8

    Vous pouvez remplacer l'ensemble de votre xsl:choose avec l'instruction: 

    <xsl:apply-templates select="autoIncludeSystem"/>

    puis ajouter deux modèles:

    <xsl:template match="autoIncludeSystem[autoincludesystem_info/@*]>
  <!-- code for elements with attributes (xsl:when) -->
</xsl:template>


<xsl:template match="autoIncludeSystem[not(autoincludesystem_info/@*)]>
  <!-- code for elements without attributes (xsl:otherwise) -->
</xsl:template>
    • Donc je peux l'utiliser <h3>System</h3><xsl:apply-templates select="autoIncludeSystem"/> directement?
    • Oui essayez et vous verrez!
    InformationsquelleAutor Emiliano Poggi
  2. 69

    Nous pouvons réaliser si l'autre par l'utilisation de code ci-dessous

    <xsl:choose>
    <xsl:when test="something to test">

    </xsl:when>
    <xsl:otherwise>

    </xsl:otherwise>
</xsl:choose>

    Voici donc ce que j'ai fait

    <h3>System</h3>
    <xsl:choose>
        <xsl:when test="autoIncludeSystem/autoincludesystem_info/@mdate"> <!-- if attribute exists-->
            <p>
                <dd><table border="1">
                    <tbody>
                        <tr>
                            <th>File Name</th>
                            <th>File Size</th>
                            <th>Date</th>
                            <th>Time</th>
                            <th>AM/PM</th>
                        </tr>
                        <xsl:for-each select="autoIncludeSystem/autoincludesystem_info">
                            <tr>
                                <td valign="top" ><xsl:value-of select="@filename"/></td>
                                <td valign="top" ><xsl:value-of select="@filesize"/></td>
                                <td valign="top" ><xsl:value-of select="@mdate"/></td>
                                <td valign="top" ><xsl:value-of select="@mtime"/></td>
                                <td valign="top" ><xsl:value-of select="@ampm"/></td>
                            </tr>
                        </xsl:for-each>
                    </tbody>
                </table>
                </dd>
            </p>
        </xsl:when>
        <xsl:otherwise> <!-- if attribute does not exists -->
            <dd><pre>
                <xsl:value-of select="autoIncludeSystem"/><br/>
            </pre></dd> <br/>
        </xsl:otherwise>
    </xsl:choose>

    Ma Sortie

    XSL si la condition else

    • +1 pour votre effort.
    InformationsquelleAutor abi1964
  3. 4

    I. Xpath 1.0 solution - utiliser cette expression XPath:

    concat(substring('String', 1 div boolean(text())),
                 ' ',
       substring('attrib values', 1 div boolean(@*))
       )

    Ici est un XSLT de vérification basée sur les:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="*[not(*)]">
     <xsl:value-of select="concat('&#10;', name(),': ')"/>

     <xsl:value-of select=
      "concat(substring('String', 1 div boolean(text())),
              ' ',
              substring('attrib values', 1 div boolean(@*))
             )
      "/>
 </xsl:template>
</xsl:stylesheet>

    lorsque cette transformation est appliquée sur le document XML fourni par le (légèrement modifiée pour être bien formé):

    <product>
    <autoIncludeUser>0 File(s) found</autoIncludeUser>
    <autoIncludeSystem>
        <autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='64' filename='AFP_p.tgp' />
        <autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='3,879' filename='AnalystsExpressionMacros.tgp' />
        <autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='475' filename='base64Converter.tgp' />
        <autoincludesystem_info mdate='08/23/2011' mtime='09:51' ampm='PM' filesize='&lt;DIR&gt;' filename='codePages' />
    </autoIncludeSystem>
    <autoIncludeStudio>0 File(s) found</autoIncludeStudio>
    <externalLibrarySystem>
        <externalLibrarySystem_info mdate='08/23/2011' mtime='09:52' ampm='PM' filesize='196,608' filename='AFPtoXML_DP.dll' />
        <externalLibrarySystem_info mdate='08/23/2011' mtime='09:52' ampm='PM' filesize='13,259' filename='ASN1toXSDRunner.jar' />
    </externalLibrarySystem>
</product>

    le voulait, résultat correct est produit:

    autoIncludeUser: String 
autoincludesystem_info:  attrib values
autoincludesystem_info:  attrib values
autoincludesystem_info:  attrib values
autoincludesystem_info:  attrib values
autoIncludeStudio: String 
externalLibrarySystem_info:  attrib values
externalLibrarySystem_info:  attrib values

    Explication Nous utilisons ces faits:

    1. Pour toute chaîne $s, substring($s, Infinity) est la chaîne vide.

    2. 1 div 0 est Infinity

    3. Par définition number(true()) est 1 et number(false()) est de 0.

      II. XPath 2.0 solution:

    C'est beaucoup plus facile dans XPath 2.0, parce que la langue est la norme de if/then/else opérateur.

    Utilisation:

    if(text())
  then 'String'
  else if(@*)
         then 'attrib values'
         else ()

    XSLT 2.0 vérification:

    <xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="*[not(*)]">
     <xsl:value-of select="concat('&#10;', name(),': ')"/>

     <xsl:value-of select=
      "if(text())
         then 'String'
         else if(@*)
           then 'attrib values'
           else ()
      "/>
 </xsl:template>
</xsl:stylesheet>

    lorsque cette transformation est appliquée sur le même document XML (ci-dessus), de nouveau le voulait, résultat correct est produit:

    autoIncludeUser: String
autoincludesystem_info: attrib values
autoincludesystem_info: attrib values
autoincludesystem_info: attrib values
autoincludesystem_info: attrib values
autoIncludeStudio: String
externalLibrarySystem_info: attrib values
externalLibrarySystem_info: attrib values
    InformationsquelleAutor Dimitre Novatchev
  4. 3

    XPath //*[not(@*)] va sélectionner tous les éléments, qui n'ont pas d'attributs.

    • un exemple sera d'une aide, aussi j'ai mis à jour avec une réponse de ma propre, vous pouvez prendre un coup d'oeil il va affecter mon travail en quelque sorte?
    • Pouvez-vous fournir de sortie souhaité en fonction de vos suggestions?
    • J'ai fourni ma sortie de ma réponse
    InformationsquelleAutor Kirill Polishchuk
  5. 2

    Vous pouvez le faire assez facilement à l'aide de xsl:choose - mais, très souvent, dans XSLT, la meilleure façon de faire un traitement conditionnel est d'écrire des différentes règles de modèle pour gérer les différentes conditions. Afin d'écrire un modèle de règle avec match="*[@*]" pour faire correspondre les éléments qui ont des attributs, et un autre avec match="*[text()]" pour faire correspondre les éléments qui ont un contenu textuel.

    • pouvez-vous me donner un exemple?
    InformationsquelleAutor Michael Kay