Avertir avant l'envoi de courriels à des domaines externes dans Outlook

Comment pouvez-vous obtenir Outlook pour vous avertir si vous êtes sur le point d'envoyer un courriel, à un domaine externe?

L'envoi de grandes quantités d'e-mails tous les jours, il est toujours possible de manière incorrecte en envoyer un à la mauvaise personne. C'est surtout un problème quand ils sont des clients ou des personnes de l'extérieur de votre entreprise.

À l'aide de Alt + Enter pour envoyer rapidement des e-mails après les taper pour moi, c'est souvent la cause que je n'ai pas vérifier les destinataires à fond.

J'ai trouvé de nombreuses applications qui n'étaient pas grandes, donc j'ai pensé que je voudrais partager la mienne ci-dessous...

InformationsquelleAutor ojhawkins | 2013-07-20
  1. 13

    Grâce ojhhawkins pour le code ci - dessus vraiment utile. J'ai fait une simple itération d'inclure une liste des adresses e-mail externes dans la boîte de messages de texte.

    Mot de prudence - j'ai remarqué que l'avertissement ne s'affiche pas lorsque vous utilisez l'Envoyer en tant Que pièce Jointe à un Courriel dans d'autres programmes, par exemple Excel, Adobe Reader etc. Comme niton souligné:

    Re:Envoyer en tant Que pièce Jointe à un Courriel dans d'autres programmes. Décrits dans les notes ici outlookcode.com/d/code/setsavefolder.htm "... ne fonctionne pas sur les messages créés avec Fichier | Envoyer des commandes dans les programmes Office ou similaire commandes dans l'Explorateur Windows ou d'autres programmes. Ces commandes appel MAPI Simple, qui contourne les fonctionnalités d'Outlook."

    Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim recips As Outlook.Recipients
    Dim recip As Outlook.Recipient
    Dim pa As Outlook.PropertyAccessor
    Dim prompt As String
    Dim strMsg As String

    Const PR_SMTP_ADDRESS As String = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"

    Set recips = Item.Recipients
    For Each recip In recips
        Set pa = recip.PropertyAccessor
        If InStr(LCase(pa.GetProperty(PR_SMTP_ADDRESS)), "@example.com") = 0 Then
            strMsg = strMsg & "   " & pa.GetProperty(PR_SMTP_ADDRESS) & vbNewLine
        End If
    Next

    If strMsg <> "" Then
        prompt = "This email will be sent outside of example.com to:" & vbNewLine & strMsg & "Do you want to proceed?"
        If MsgBox(prompt, vbYesNo + vbExclamation + vbMsgBoxSetForeground, "Check Address") = vbNo Then
            Cancel = True
        End If
    End If
End Sub

    Pour ajouter ce code à votre application Outlook:

    • Si vous ne pouvez pas voir l'onglet Développeur dans le ruban, aller à Fichier/Options, choisissez Personnaliser le Ruban sur la gauche, et cochez Développeur sur la droite.
    • De la Développeur onglet choisir Visual Basic.
    • Développez Projet1, Objets Microsoft Outlook, puis double-cliquez sur ThisOutlookSession (en haut à gauche).
    • Coller le code ci-dessus dans le module.
    • Remplacer le "example.com" dans le code copié à votre domaine.
    • Fermez l'éditeur VBA et enregistrez les modifications dans le module.
    • Sur le Développeur onglet, cliquez sur de Sécurité des Macros, et de modifier le niveau de Notifications pour toutes les macros ou moins.
    • Redémarrez Outlook. (Le code ci-dessus va pas réagir autrement.)
    • Re: Envoyer en tant Que pièce Jointe à un Courriel dans d'autres programmes. Décrits dans les notes ici outlookcode.com/d/code/setsavefolder.htm "... ne fonctionne pas sur les messages créés avec Fichier | Envoyer des commandes dans les programmes Office ou similaire commandes dans l'Explorateur Windows ou d'autres programmes. Ces commandes appel MAPI Simple, qui contourne les fonctionnalités d'Outlook."
    • arrivé ici après près de faire une carrière à réglage erreur. Merci pour l'inscription que pour les non-VBA devs. J'espère que je vais pas faire cette erreur!
    • Le site web "schemas.microsoft.com/mapi/proptag/0x39FE001E" n'existe plus. comment puis-je faire ce travail?
    InformationsquelleAutor matho
  2. 2

    1. Ajouter le code ci-dessous pour les Application_ItemSend événement dans Outlook & changer de domaine pour votre propre

    2. Changer le Macro Security soit (Notifcations pour toutes les macros ou Activer toutes les macros)

    Ce qui vous donnera un avertissement avant l'envoi si 1 ou plusieurs de vos TO,CC ou BCC adresse n'est pas dans votre domaine (par exemple ci-dessous @mycompany.com.au)

    Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim recips As Outlook.Recipients
    Dim recip As Outlook.Recipient
    Dim pa As Outlook.PropertyAccessor
    Const PR_SMTP_ADDRESS As String = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
    Set recips = Item.Recipients
    For Each recip In recips
        Set pa = recip.PropertyAccessor
        If InStr(LCase(pa.GetProperty(PR_SMTP_ADDRESS)), "@mycompany.com.au") = 0 Then
            If MsgBox("Send mail to external domain?", vbYesNo + vbQuestion + vbMsgBoxSetForeground, "Check Address") = vbNo Then
                Cancel = True
                Exit Sub
            Else
                Exit Sub
            End If
        End If
    Next
End Sub
    • Cela fonctionne très bien pour la plupart des cas, à l'exception des Listes de Distribution qui contiennent des entrées externes de domaine (également ne pas ramasser les Contacts de Messagerie qui sont " Masquer dans la liste d'adresses globale).
    InformationsquelleAutor ojhawkins
  3. 1

    J'ai trouvé deux add-in pour microsoft Outlook qui fait la même chose si vous ne souhaitez pas utiliser VBA,

    InformationsquelleAutor Nic